ods graphics on;
title "Water Data - Univariate Exploration";
data water;
    infile 'C:\Users\sungkyu\Dropbox\Teaching\1301-StatisticalPackages\datasets\water.dat';
    input flag $ 1 Town $ 2-18 Mortal 19-22 Hardness 25-27;
    if flag='*' then loc='north';
        else loc='south';
run;

data water_formattedinput;
    infile 'C:\Users\sungkyu\Dropbox\Teaching\1301-StatisticalPackages\datasets\water.dat';
    input flag $1. Town $17. Mortal 4. @25 Hardness 3.;
    if flag='*' then loc='north';
        else loc='south';
	proc print data = water_formattedinput;
run; 


proc univariate data=water normal plot ;
  var mortal hardness;
  histogram mortal hardness / normal lognormal exponential weibull;
  qqplot mortal hardness / exponential;
  probplot mortal hardness;
run; 


proc univariate data=water cibasic mu0=10;
  var mortal hardness;
run; 

title "Water Data - Bivariate Exploration";
proc sgplot data=water;
  scatter y=mortal x=hardness;
run;
proc corr data=water;
  var mortal hardness;
run;


proc sgplot data=water;
  scatter y=mortal x=hardness / group=loc;
run;
proc sort;
   by loc;
run;
proc corr data=water;
  var mortal hardness;
  by loc;
run;

proc kde data=water;
  bivar mortal hardness /plots=surface;
  by loc;
run;



title "Water Data - loc Tests";

ods graphics on;
data water;
   set water;
   lhardnes=log(hardness);
run;
proc ttest data=water;
   class loc;
   var mortal hardness lhardnes;
run;
proc npar1way data=water wilcoxon;
   class loc;
   var hardness;
run;

title "Slimming Data - Paired T-tests";

data slimmingclub; /* formatted input */ 
  infile 'C:\Users\sungkyu\Dropbox\Teaching\1301-StatisticalPackages\datasets\slimmingclub2.dat';
  input @20 team $7. startweight 4. weightnow 3.;
  if team = 'yellow' or team = 'red' then delete;
  weightloss = startweight - weightnow;
run;
proc ttest data = slimmingclub;
   paired startweight*weightnow;
run;
proc univariate data = slimmingclub;
   var weightloss;
run;